500 KEY(1) ON:ON KEY(1) GOSUB 560
505 KEY(2) ON:ON KEY(2) GOSUB 575
510 KEY(3) ON:ON KEY(3) GOSUB 590
515 KEY(4) ON:ON KEY(4) GOSUB 620
520 KEY(5) ON:ON KEY(5) GOSUB 605
525 KEY(6) ON:ON KEY(6) GOSUB 635
530 KEY(10) ON:ON KEY(10) GOSUB 750
535 CLS:LOCATE 3,1:PRINT " ";:COLOR 9,0:PRINT "KEY";:COLOR 7,0:PRINT "     ";:COLOR 9,0:PRINT "PARAMETER AS SET";:COLOR 7,0:PRINT
540 GOSUB 650:GOSUB 660:GOSUB 690:GOSUB 705:GOSUB 720:GOSUB 740
545 LOCATE 19,1:PRINT "Depress the appropriate function key to change the parameter as set."
550 PRINT:PRINT "Depress function key ";:COLOR 23,0:PRINT "F10";:COLOR 7,0:PRINT " to escape."
555 GOTO 555
560 IF DISK$="B:" THEN DISK$="A:" ELSE DISK$="B:"
565 GOSUB 650
570 RETURN
575 PRTFLG=(PRTFLG+1) MOD 3
580 GOSUB 660
585 RETURN
590 IF SCRFLG=1 THEN SCRFLG=0 ELSE SCRFLG=1
595 GOSUB 690
600 RETURN
605 IF PLAFLG=1 THEN PLAFLG=0 ELSE PLAFLG=1
610 GOSUB 720
615 RETURN
620 MAXL=MAXL+250:IF MAXL>15000 THEN MAXL=250
625 GOSUB 705
630 RETURN
635 CLS:LOCATE 12,1:INPUT "Are you sure you want to exit to DOS";A$
640 IF A$="YES" OR A$="yes" THEN CLS:SYSTEM
645 GOTO 500
650 LOCATE 5,1:PRINT "  F1     Data will be read from diskette in drive ";:COLOR 1,0:PRINT DISK$;:COLOR 7,0:PRINT "."
655 RETURN
660 LOCATE 7,1:PRINT "  F2     Output will be sent to ";
665 COLOR 1,0:ON PRTFLG+1 GOTO 670,675,680
670 PRINT "the screen.";:GOTO 685
675 PRINT "the printer.";:GOTO 685
680 PRINT "a specified file.";
685 COLOR 7,0:PRINT "      ":RETURN
690 LOCATE 9,1:PRINT "  F3     Output to the screen will be ";
695 COLOR 1,0:IF SCRFLG THEN PRINT "continuous scroll.";:COLOR 7,0:PRINT ELSE PRINT "page formatted.";:COLOR 7,0:PRINT "     "
700 RETURN
705 LOCATE 11,1:PRINT "  F4     Maximum number of bases allowed is ";
710 COLOR 1,0:PRINT USING "#####";MAXL;:COLOR 7,0:PRINT "."
715 RETURN
720 LOCATE 13,1:PRINT "  F5     An audible tone ";
725 COLOR 1,0:IF PLAFLG THEN PRINT "will";:COLOR 7,0 ELSE PRINT "will not";:COLOR 7,0
730 PRINT " be sounded for each key depressed.     "
735 RETURN
740 LOCATE 15,1:PRINT "  F6     Use this key to exit to DOS.";
745 RETURN
750 GOTO 10
1000 END