500 CLS:CHRPTCH=1:LNPTCH=1:BF=2:MARG=0
510 KEY(1) ON:ON KEY(1) GOSUB 610
520 KEY(2) ON:ON KEY(2) GOSUB 690
530 KEY(3) ON:ON KEY(3) GOSUB 780
540 KEY(4) ON:ON KEY(4) GOSUB 810
550 KEY(10) ON:ON KEY(10) GOSUB 850
560 LOCATE 5,1:PRINT " ";:COLOR 9,0:PRINT "KEY";:COLOR 7,0:PRINT "     ";:COLOR 9,0:PRINT "PARAMETER AS SET";:COLOR 7,0
570 GOSUB 640:GOSUB 720:GOSUB 780:GOSUB 840
580 LOCATE 17,1:PRINT "Strike the appropriate function key to change the parameter as set."
590 LOCATE 19,1:PRINT "Use function key ";:COLOR 23,0:PRINT "F10";:COLOR 7,0:PRINT " to escape."
600 GOTO 600
610 CHRPTCH=CHRPTCH+1:IF CHRPTCH>3 THEN CHRPTCH=1
620 GOSUB 640
630 RETURN
640 LOCATE 7,1:PRINT "  F1     Character pitch is set as ";
650 ON CHRPTCH GOTO 660,670,680
660 COLOR 1,0:PRINT "pica";:COLOR 7,0:PRINT ".        ":LPRINT CHR$(27)+"N";:RETURN
670 COLOR 1,0:PRINT "elite";:COLOR 7,0:PRINT ".       ":LPRINT CHR$(27)+"E";:RETURN
680 COLOR 1,0:PRINT "compressed";:COLOR 7,0:PRINT ".  ":LPRINT CHR$(27)+"Q";:RETURN
690 LNPTCH=LNPTCH+1:IF LNPTCH>3 THEN LNPTCH=1
700 GOSUB 720
710 RETURN
720 LOCATE 9,1:PRINT "  F2     Line feed pitch is set as ";
730 ON LNPTCH GOTO 740,750,760
740 COLOR 1,0:PRINT "1/6 inch";:COLOR 7,0:PRINT ".":LPRINT CHR$(27)+"A";:RETURN
750 COLOR 1,0:PRINT "1/8 inch";:COLOR 7,0:PRINT ".":LPRINT CHR$(27)+"B";:RETURN
760 COLOR 1,0:PRINT "N/144";:COLOR 7,0:PRINT ".   ":LOCATE 23,1:INPUT "Enter a number between 0 and 99: ",N
770 LOCATE 23,1:PRINT STRING$(40,32):LOCATE 9,36:COLOR 1,0:PRINT USING "##/144";N;:COLOR 7,0:PRINT ".   ":LPRINT CHR$(27)+"T"+RIGHT$(STR$(N),2);:RETURN
780 LOCATE 11,1:PRINT "  F3     Characters will be printed in ";
790 COLOR 1,0:IF BF=1 THEN BF=2:PRINT "bold";:LPRINT CHR$(27)+"!"; ELSE BF=1:PRINT "normal";:LPRINT CHR$(27)+CHR$(34);
800 COLOR 7,0:PRINT " print.  ";:RETURN
810 LOCATE 23,1:INPUT "Enter a number between 0 and 80: ",MARG:LOCATE 23,1:PRINT STRING$(40,32)
820 GOSUB 840
830 RETURN
840 LOCATE 13,1:PRINT "  F4     The left margin will be ";:COLOR 1,0:PRINT MARG;:COLOR 7,0:PRINT " spaces in.   ":LPRINT CHR$(27)+"L"+" "+RIGHT$(STR$(MARG),2);:RETURN
850 GOTO 10
1000 END